{
  description = "FredOS NixOS configuration";

  inputs = {
    nixpkgs-stable.url = "github:NixOS/nixpkgs/nixos-25.11";
    nixpkgs.url = "github:NixOS/nixpkgs/nixos-unstable";
    home-manager-stable = {
      url = "github:nix-community/home-manager/release-25.11";
      inputs.nixpkgs.follows = "nixpkgs-stable";
    };

    # Unstable HM for Hyprland Lua config support (configType = "lua",
    # available since HM master / future 26.05).
    home-manager = {
      url = "github:nix-community/home-manager";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    zen-browser = {
      url = "github:0xc000022070/zen-browser-flake";
      inputs = {
        nixpkgs.follows = "nixpkgs-stable";
        home-manager.follows = "home-manager-stable";
      };
    };

    nix-cachyos-kernel.url = "github:xddxdd/nix-cachyos-kernel/release";

    proton-cachyos-nix.url = "github:powerofthe69/proton-cachyos-nix";

    # Pin Hyprland to upstream so we get the 0.52.2+ fixes ahead of
    # nixos-25.11's slower bump cadence. Doesn't follow our nixpkgs —
    # upstream needs newer stdenv than 25.11 ships.
    hyprland.url = "github:hyprwm/Hyprland";

    anyrun = {
      url = "github:anyrun-org/anyrun";
      inputs.nixpkgs.follows = "nixpkgs";
    };

    stylix.url = "github:nix-community/stylix";
    stylix-stable = {
      url = "github:nix-community/stylix/release-25.11";
      inputs.nixpkgs.follows = "nixpkgs-stable";
    };
  };
  outputs =
    { self
    , nixpkgs-stable
    , nixpkgs
    , home-manager-stable
    , home-manager
    , zen-browser
    , nix-cachyos-kernel
    , hyprland
    , anyrun
    , stylix
    , stylix-stable
    , proton-cachyos-nix
    , ...
    } @ inputs:
    let
      system = "x86_64-linux";
      mkHost = hostname: pkgsInput: hmInput: extraModules: pkgsInput.lib.nixosSystem {
        inherit system;
        specialArgs = { inherit inputs; pkgs-unstable = nixpkgs.legacyPackages.${system}; };
        modules = [
          ./hosts/${hostname}.nix
          ./hosts/hardware/${hostname}.nix
          ./common.nix
          hmInput.nixosModules.home-manager
        ] ++ extraModules;
      };
    in
    {
      nixosConfigurations = {
        # Gaming and Macbook use nixpkgs unstable — required by home-manager
        # unstable which needs lib/services/lib.nix added in nixpkgs after 25.11.
        FredOS-Gaming      = mkHost "FredOS-Gaming"  nixpkgs      home-manager [ stylix.nixosModules.stylix ./settings/stylix.nix ];
        FredOS-Mediaserver = mkHost "FredOS-Mediaserver" nixpkgs-stable home-manager-stable [ stylix-stable.nixosModules.stylix ./settings/stylix.nix ];
        FredOS-Macbook     = mkHost "FredOS-Macbook" nixpkgs      home-manager [ stylix.nixosModules.stylix ./settings/stylix.nix ];
      };
    };
}
