nixos/flake.nix

{
  description = "FredOS NixOS configuration";

  nixConfig = {
    extra-substituters =[
      "https://cuda-maintainers.cachix.org"
    ];
    extra-trusted-public-keys =[
      "cuda-maintainers.cachix.org-1:0dq3bujKpuEPMCX6U4WylrUDZ9JyUG0VpVZa7CNfq5E="
    ];
  };

  inputs = {
    nixpkgs-stable.url = "github:NixOS/nixpkgs/nixos-25.11";
    home-manager-stable = {
      url = "github:nix-community/home-manager/release-25.11";
      inputs.nixpkgs.follows = "nixpkgs-stable";
    };

    zen-browser = {
      url = "github:0xc000022070/zen-browser-flake";
      inputs = {
        nixpkgs.follows = "nixpkgs-stable";
        home-manager.follows = "home-manager-stable";
      };
    };

    nix-cachyos-kernel.url = "github:xddxdd/nix-cachyos-kernel/release";

    # Pin Hyprland to upstream so we get the 0.52.2+ fixes ahead of
    # nixos-25.11's slower bump cadence. Doesn't follow our nixpkgs —
    # upstream needs newer stdenv than 25.11 ships.
    hyprland.url = "github:hyprwm/Hyprland";

    # Stylix release branch matching nixos-25.11. Master references
    # options (services.displayManager.generic) that only exist in
    # newer nixpkgs schemas.
    stylix.url = "github:nix-community/stylix/release-25.11";
  };
  outputs =
    { self
    , nixpkgs-stable
    , home-manager-stable
    , zen-browser
    , nix-cachyos-kernel
    , hyprland
    , stylix
    , ...
    } @ inputs:
    let
      system = "x86_64-linux";
      mkHost = hostname: pkgsInput: hmInput: pkgsInput.lib.nixosSystem {
        inherit system;
        specialArgs = { inherit inputs; };
        modules = [
          ./hosts/${hostname}.nix
          ./hosts/hardware/${hostname}.nix
          ./common.nix
          hmInput.nixosModules.home-manager
        ];
      };
    in
    {
      nixosConfigurations = {
        FredOS-Gaming      = mkHost "FredOS-Gaming"      nixpkgs-stable home-manager-stable;
        FredOS-Mediaserver = mkHost "FredOS-Mediaserver" nixpkgs-stable home-manager-stable;
        FredOS-Macbook     = mkHost "FredOS-Macbook"     nixpkgs-stable home-manager-stable;
      };
    };
}