nixos/home-manager/fred.nix

# home-manager/fred.nix
{ config, pkgs, lib, inputs, osConfig, ... }:
let
  isDesktop = lib.elem osConfig.networking.hostName [ "FredOS-Gaming" "FredOS-Macbook" ];
in
{
  home.stateVersion = "25.11";

  home.packages = with pkgs; [
    #
  ];

  home.file.".config/nixpkgs/config.nix".text = ''
    { allowUnfree = true; }
  '';

  # Wallpaper source — consumed by stylix's image option (set in
  # settings/stylix.nix) and by quickshell's wallpaper layer.
  home.file.".local/share/backgrounds/wallpaper.png".source =
    "${inputs.self}/walls/wallpaper.png";

  # btop — stylix's btop target writes the colour theme; we keep our
  # non-colour preferences here.
  programs.btop = {
    enable = true;
    settings = {
      theme_background = false;
      vim_keys = false;
      proc_filter_kernel = true;
    };
  };

  # Ghostty — stylix's ghostty target writes the colour theme.
  programs.ghostty = lib.mkIf isDesktop {
    enable = true;
    settings = {
      font-family = "CaskaydiaCove NF";
      font-size = 11;
      font-thicken = true;
      window-padding-x = 10;
      window-padding-y = 10;
      window-padding-balance = true;
      background-opacity = 0.98;
      confirm-close-surface = false;
      gtk-titlebar = false;
      gtk-single-instance = true;
      # keeps the warm instance alive with zero windows
      quit-after-last-window-closed = false;
      cursor-style = "bar";
      cursor-style-blink = true;
    };
  };

  # spotify-player — native librespot TUI replacing the Electron Spotify app.
  # stylix's spotify-player target writes the colour theme.
  # MPRIS (quickshell's media card), notifications and streaming are all on by
  # default on Linux, so no settings needed here.
  programs.spotify-player = lib.mkIf isDesktop {
    enable = true;
  };

  # Upstream ships no .desktop file (TUI only), so the launcher can't find it.
  xdg.desktopEntries.spotify-player = lib.mkIf isDesktop {
    name = "Spotify Player";
    genericName = "Music Player";
    exec = "ghostty --title=spotify-player -e spotify_player";
    icon = "spotify";
    terminal = false;
    categories = [ "Audio" "Music" "Player" "AudioVideo" ];
  };

  # Warm Ghostty instance — new windows attach via gtk-single-instance.
  systemd.user.services.ghostty-daemon = lib.mkIf isDesktop {
    Unit = {
      Description = "Ghostty warm instance (no window)";
      After = [ "graphical-session.target" ];
      PartOf = [ "graphical-session.target" ];
    };
    Service = {
      Type = "simple";
      ExecStart = "${pkgs.ghostty}/bin/ghostty --initial-window=false";
      Restart = "always";
    };
    Install.WantedBy = [ "graphical-session.target" ];
  };

}